最終更新: 2018/10/16(Tue)21:46

自作と修理を愛するブログ。トイラジ、電子工作、ボルティー、NucleusCMS 、いろいろゴソゴソやってます
3Dプリンター / 3Dスキャナーも -kyu-

Home

アナログタコメータをつくる(5) スケッチ、そして完成

さて肝心のスケッチです。前に書いた通りライブラリがふたつ必要です。

Arduino-OBD2-Async
https://github.com/vova-ivanyshyn/Arduino-OBD2-Async

Switec X25 library
https://github.com/clearwater/SwitecX25

ライブラリは適当な場所に入れておきます。

スケッチを簡単に説明すると、ステッピングモータの目標値は0.1秒ごとに更新し、モータの動作自体は毎ループごとに行います。文字盤のバックライトは5秒毎に更新。

たぶんもっといいやりかたがあるんでしょうね。シロウトのヘナチョコプログラムだと思って温かい目で見てやってください。何かあったらコメント欄からお知らせいただけると嬉しいです。

#include “SwitecX25.h”
#include “OBD.h”

SwitecX25 motor(315*3, 4, 5, 6, 7);
COBD obd;

// ステップモーター定数
const int PULSE_PER_REV = 315*3; // ステップモータ全体のパルス数
const int MAX_DISP_REV = 8000; // 表示最大回転数(rpm)
const int VIEW_ANGLE = 315; // 使用範囲(deg)
const float CONV = (1 / (float)MAX_DISP_REV) * ((float)VIEW_ANGLE / 315.0) * (float)PULSE_PER_REV;
// 回転数*CONV=ステップ数 : CONV = (1/8000)*(315/315)*315*3 = 0.118125 ->0.12

// エンジン回転数変数
int CurrentRpm = 0; //現在のエンジン回転数
int PreviousRpm = 0; //前回のエンジン回転数

// 更新頻度変数
const int UpdateInterval1 = 100;  // 更新間隔(高頻度) ミリ秒
const int UpdateInterval2 = 5000;  // 更新間隔(低頻度) ミリ秒
unsigned long PreviousUpdate1 = 0;   // 前回の更新時(高頻度)
unsigned long PreviousUpdate2 = 0;   // 前回の更新時(低頻度)

// 照明変数
const int LedPin = 9;
const int CdsPin = 0;
int CdsValue = 0;

void setup()
{
  for ( int i = 30; i < LedValue(); i += 1 ) {
    analogWrite( LedPin, i );
    delay( 10 );
  }
  motor.zero();
  delay(200);
  motor.setPosition(MAX_DISP_REV * CONV);
  motor.updateBlocking();
  delay(200);
  motor.setPosition(0);
  motor.updateBlocking();
  delay(200);
  obd.begin();
  while (!obd.init(PROTO_AUTO));
}

void loop()
{
  unsigned long CurrentTime = millis(); // 現在時
  motor.update(); //メータを駆動 (1step/Loop)

  if (!obd.asyncInProgress()) {
    obd.asyncRequest(PID_RPM); //リクエスト送信
  }
  
  if (CurrentTime - PreviousUpdate1 >= UpdateInterval1) { //更新(高頻度)
    int val = 0;
    if (obd.asyncGet(val)) {
      CurrentRpm = val % 10000;
      if (abs(PreviousRpm - CurrentRpm) > 9){ //前回との差が一桁なら更新しない
        motor.setPosition((float)CurrentRpm * (float)CONV); //目標位置設定
        PreviousRpm = CurrentRpm;
      }
    }
    PreviousUpdate1 = CurrentTime;
  }

  if (CurrentTime - PreviousUpdate2 >= UpdateInterval2) { //更新(低頻度)
    analogWrite( LedPin, LedValue() );
    PreviousUpdate2 = CurrentTime;
  }

  if (obd.errors >= 2) {
    reconnect();
    setup();
  }

}

void reconnect()
{
  for (uint16_t i = 0; !obd.init(PROTO_AUTO); i++) {
    delay(3000);
  }
}

int LedValue()
{
  int result;
  CdsValue = analogRead(CdsPin); // だいたい 500-1000
  result = -0.3*(float)CdsValue+350;
  if (result > 255){
    result = 255;
  }
  return result;
}

さあ一気に仕上げていきますよ。

★パテ修正 ★パテ修正
3Dプリンタで打ちっぱなしだとどうしても積層痕が目立つので、パテで表面処理をします。ポリパテのほうが良いかと思いつつ、手元の在庫を切らしていたのでタミヤのラッカーパテを使用。全体によく擦り込みつつ、大きくヒケているところには数回に分けて盛り付けます。強度は期待できませんが仕上がりは良いはず。

★サフ吹き
パテ盛りとペーパー掛けを繰り返して納得できたら洗浄しサーフェイサーを吹いて確認。そこで見つけたアラをまたパテとペーパーで修正。ってなループをしばらく繰り返します。
タミヤ研磨スポンジシートの400番から始めて、クレオスのサフ500番、タミヤのペーパー600番、800番、サフ1000番、ペーパー1000番まで。写真はサフ1000番の直後ですね。
面出しは苦手です。平面ならまだしも円筒は難しい。だんだん嫌になってきたのでほどほどのところでやめておきます。

★塗装
ハンドピースで塗装。クレオスのラッカー黒。だいたいいつもは半ツヤ程度でごまかすんですが今回はツヤ有りブラックで。
ツヤ有り塗装はエア圧強め塗料多めで近めから吹くと良いです。希釈は通常通り薄めで、数回重ねたら最後は垂れる寸前くらいまで吹くとしっとりしたツヤが得られます。
って初めてやったので偉そうなことは言えませんハイwww
持ち手はトイレットペーパーの芯です。このくらいの大きさの対象物のときはこれが最高に使いやすいです。
この後塗膜保護と見栄えのためクリアを重ねて水研ぎしピアノブラック調の予定でしたが、面倒くさくなったのでこのままで。

★文字盤
文字盤はとあるプロ向けの 2D プリンタを使用。ボルティーのタコメータ盤面をつくったときに使ったのと同系統のプリンタです。家電量販店には売ってません。紫外線硬化タイプのインクを使います。
0.3mm プラバンにダイレクト印刷しました。濃度を数パターン試して、最終的には 400% としました。
写真だと表面がザラザラな感じですが実物では気になりません。前はつや消しコートしましたが、直射日光を浴びることはまずないはずなのでこれもやめ。

★組み立て ★上から
部品が揃いました。組み立てです。基本的には全てはめ込みです。
黒い本体部分、表面がうねっているのがバレバレですね。あらためてプラモデルのひとは凄いなと思います。
メータ正面のガラス押さえ用の輪っかは、これまたクレオスラッカーのシルバー。仕上げも製面もちゃんとしていなかったので筆塗りです。もうちょっとアルミっぽいシルバーのほうが良かったかも。まあいいや。
正面にガラスというか透明な保護板を入れる予定でしたが、単車と違って防水にする必要もないし、透明プラバンをきれいに丸く切り出す自信もなかったのでとりあえずなしで。

★裏側
裏側には大穴が空いてます。設置すれば見えないので問題なし。自作モノの場合は特に、手抜きというか割り切りが大事ですよ。ははっ。

★発光テスト
机上で発光テスト。針の光が漏れててガラス押さえが赤くなっちゃってますね。LED の周囲に遮光板をつけることにします。
ちょっと文字盤が小さかったなぁ。周りからバックライトがモレモレです。あまりに気になるようなら作り直しますか。

★クルマに取り付け(正面) ★斜めから
クルマに取り付けました。おー、いいですね。なかなカッコイイです。

★夜間照明(正面) ★斜めから
夜になるのを待って照明の確認。
視認性はばっちりです。文字盤のゼロが暗いですね。モータがあるのでうまく光が回り込まなかった模様。まあいいや。


ちょっと荒いですが昼間撮影した動画です。オープニングセレモニーが意外とタイミングよいです。

1200円程度でつくった割にはよくできたと思います。Arduino についてもいい勉強ができました。
これにて完成。

コメント

この記事へのコメントはありません

コメントを投稿

( *は必須項目です )

%3c%69%6e%70%75%74%20%74%79%70%65%3d%22%68%69%64%64%65%6e%22%20%6e%61%6d%65%3d%22%6e%70%5f%70%72%6f%74%65%63%74%62%79%6d%64%35%22%20%76%61%6c%75%65%3d%22%30%39%65%39%35%62%66%38%61%36%35%64%33%62%66%61%34%36%30%36%33%66%65%34%66%61%37%32%35%38%61%30%22%3e %3c%69%6e%70%75%74%20%74%79%70%65%3d%22%68%69%64%64%65%6e%22%20%6e%61%6d%65%3d%22%6e%70%5f%70%72%6f%74%65%63%74%62%79%6d%64%35%5f%68%61%73%68%22%20%76%61%6c%75%65%3d%22%61%39%35%37%61%35%62%39%37%37%31%38%31%66%33%63%34%65%65%64%61%38%36%66%36%61%34%65%38%38%35%39%22%3e

サイト内検索

↑ページ先頭へ

1311719 [Mode]
Copyright © kyu-weblog All Rights Reserved. Powered by Nucleus CMS v3.71 管理